Zugriff auf die Junit-Testanzahl im Jenkins Pipeline-Projekt

Um die Antwort von @ vikramsjn zu erweitern, verwende ich die Testzusammenfassung in meiner Jenkinsfile :

import hudson.tasks.test.AbstractTestResultAction
import hudson.model.Actionable

@NonCPS
def getTestSummary = { ->
    def testResultAction = currentBuild.rawBuild.getAction(AbstractTestResultAction.class)
    def summary = ""

    if (testResultAction != null) {
        def total = testResultAction.getTotalCount()
        def failed = testResultAction.getFailCount()
        def skipped = testResultAction.getSkipCount()

        summary = "Test results:\n\t"
        summary = summary + ("Passed: " + (total - failed - skipped))
        summary = summary + (", Failed: " + failed)
        summary = summary + (", Skipped: " + skipped)
    } else {
        summary = "No tests found"
    }
    return summary
}

Ich verwende dann diese Methode, um meine Variable testSummary zu instanziieren:

def testSummary = getTestSummary()

Dies wird etwas ähnliches zurückgeben:

"Test results:
     Passed: 123, Failed: 0, Skipped: 0"

Zunächst einmal danke ich Ihnen für die obigen Antworten. Sie haben mir viel Zeit gespart, ich habe die vorgeschlagene Lösung in meiner Pipeline verwendet. Ich habe jedoch nicht "Whitelisting" verwendet und es funktioniert gut . Ich verwende gemeinsam genutzte Bibliotheken für Jenkins Pipeline. Hier ist ein Teil dieser gemeinsam genutzten Bibliothek mit Pipeline und Verwendung von Methoden, um die Anzahl zu ermitteln:

import hudson.model.*
import jenkins.model.*
import hudson.tasks.test.AbstractTestResultAction

def call(Closure body) {
    ...

    def emailTestReport = ""

    pipeline {
        ...

        stages{
            stage('Test'){
                ...
                post {
                    always {
                        junit 'tests.xml'

                        script {
                            AbstractTestResultAction testResultAction =  currentBuild.rawBuild.getAction(AbstractTestResultAction.class)
                            if (testResultAction != null) {
                                def totalNumberOfTests = testResultAction.totalCount
                                def failedNumberOfTests = testResultAction.failCount
                                def failedDiff = testResultAction.failureDiffString
                                def skippedNumberOfTests = testResultAction.skipCount
                                def passedNumberOfTests = totalNumberOfTests - failedNumberOfTests - skippedNumberOfTests
                                emailTestReport = "Tests Report:\n Passed: ${passedNumberOfTests}; Failed: ${failedNumberOfTests} ${failedDiff}; Skipped: ${skippedNumberOfTests}  out of ${totalNumberOfTests} "
                            }
                        }

                        mail to: '[email protected]',
                        subject: "Tests are finished: ${currentBuild.fullDisplayName}",
                        body: "Tests are finished  ${env.BUILD_URL}\n  Test Report: ${emailTestReport} "
                    }

                }
            }
        }
    }
}

p.s. Wenn ich emailTestRepot als lokale Variable im Skript "section" erstelle, erhalte ich die nächste Ausnahme:

an exception which occurred:
    in field locals
    in field parent
    in field caller
    in field e
    in field program
    in field threads
    in object [email protected]
Caused: Java.io.NotSerializableException: hudson.tasks.junit.TestResultAction
...

Ich hatte viel zu kämpfen mit dem Versuch, diese Java.io.NotSerializableException zu beheben. Nach meinem Verständnis musste ich "Whitelisting" verwenden, um NotSerializableException zu verhindern. Aber ich wollte es wirklich nicht und als ich "def emailTestReport" aus der Pipeline herausgezogen habe, hat es gut funktioniert.